WorldWeaver — Exemplos do Dialeto

Estrutura do arquivo

Um único texto contendo a história e, ao final, o catálogo de entidades.

copiar@world tavern
:: inicio
Texto da cena…

@world ruinas
:: entrada
Outra cena…

@entities
character Helm:
  apelido: "Helm"
  name: "Willahelm"
  descricao: "Caçador taciturno."
@endentities

Use apenas letras, números, _ e - em IDs (mundos, passagens, entidades).

@world — Mundos

Agrupa passagens (capítulos/mapas). Sem @world, o motor usa um mundo padrão.

copiar@world tavern
:: inicio
Você está na taverna.

@world ruinas
:: entrada
Eco frio nas fendas.

:: — Passagens

Cada cena navegável começa com :: nome. A primeira costuma ser :: inicio.

copiar:: sala
A sala é ampla e iluminada.

Texto & parágrafos

Escreva normalmente. Linha em branco cria um novo parágrafo.

copiarChovia quando você entrou.

O cheiro de pão recém-assado veio da cozinha.

@ID — Referências de entidades

Insira dados do catálogo no meio do texto.

• @ID usa a ordem de exibição do tema (padrão: apelido → name → nome)
• @ID/campo força um campo específico
• @ID?campo1|campo2 usa o primeiro campo disponível dessa ordem

copiar@Helm ajusta a capa.
@Helm/apelido observa você.
@Helm?apelido|name sorri.

[[…]] — Links (com condição opcional)

Mostra um botão que leva a outra passagem. Pode ter condição com if:.

copiar[[Olhar ao redor -> sala]]
[[Abrir com a chave -> ruinas/entrada | if: tem_chave]]

Para trocar de mundo, use mundo/passagem.

«choice» — Bloco de escolhas

Cria um menu e salva a escolha numa variável.

copiar<<choice Bebida as Bebida1>>
- Cerveja
- Vinho do Mar Recurvo
<</choice>>

<<if Bebida1 == "Vinho do Mar Recurvo">>
O aroma é doce.
<<else>>
A espuma amarga reconforta.
<</if>>

O player pausa a renderização na primeira interação (choice/link/input). O restante aparece depois da ação.

Variáveis, {{interpolação}} e «set»

copiar<<set energia = 10>>
<<set nome = "Ky">>
Você tem {{energia}} de energia, {{nome}}.

Tipos: booleano (true/false), número, string entre aspas, ou copiar de outra variável.

«goto» — Saltos

copiar<<goto sala>>
<<goto ruinas/entrada>>

«if/else» — Condicionais de bloco

Mostra/oculta trechos, menus e saltos.

copiar<<if tem_chave>>
A fechadura gira com um clique.
<<else>>
Sem a chave, o portão não cede.
<</if>>

Não há elseif nativo. Emule com if dentro do else, ou use condições combinadas.

«input» — Campo de texto

Coleta um valor digitado pelo leitor e salva numa variável. Aceita placeholder, required, min, max e pattern.

copiar<<input "Como você quer se chamar?" as nome placeholder:"Digite seu nome" required min:1 max:30 pattern:"^[A-Za-zÀ-ÿ\\s'-]+$">>

Prazer em te conhecer, {{nome}}.

@entities — Catálogo

Ficha de personagens, lugares, itens etc. (usados pelas referências @ID no texto).

copiar@entities
character Helm:
  name: "Willahelm"
  apelido: "Helm"
  descricao: "Caçador taciturno de Monte Dourado."

place MonteDourado:
  nome: "Monte Dourado"
  clima: "chuvoso"
@endentities

Troca de mundos

Use mundo/passagem no destino do link ou do <<goto>>.

copiar@world tavern
:: inicio
[[Ir às ruínas -> ruinas/entrada]]

@world ruinas
:: entrada
[[Voltar à taverna -> tavern/inicio]]

Condições avançadas (and/or/not, parênteses)

Disponível para links com | if: e para <<if ...>>.

copiar<<set tem_chave = true>>
<<set bebida = "Vinho">>
<<set sigilo = false>>

[[Abrir -> sala | if: tem_chave and (sigilo or bebida == "Vinho")]]
[[Bater -> beco  | if: not tem_chave or bebida == "Cerveja"]]

<<if tem_chave and not (bebida == "Cerveja")>>
A fechadura gira e o aroma do vinho acompanha você.
<<else>>
Você hesita na porta.
<</if>>

Comparação de string sempre com aspas: var == "texto".

Padrões úteis

Choice que decide e avança sem botão

copiar"Se molhou muito?"

<<choice Molhado? as Var_Molhado1>>
- Pouco
- Mais ou menos
- Bastante
<</choice>>

<<if Var_Molhado1 == "Bastante">><<goto toalhas>><</if>>
<<if Var_Molhado1 == "Pouco" or Var_Molhado1 == "Mais ou menos">><<goto entrada>><</if>>

Vários links juntos (sem choice)

copiar[[Mercado -> cidade/mercado]]
[[Portão Leste -> cidade/portao | if: tem_chave]]

Debug rápido

copiarEscolha: {{Var_Molhado1}}
Chave? {{tem_chave}}

Lembre: a primeira interação na tela (choice/link/input) pausa o restante da passagem nesta etapa.

Dicas de debug

• Mostre variáveis com {{nome_da_variavel}}.
• Se um link “não vai”, confirme se o destino existe (mundo/passagem).
• Comparações de string: use aspas e evite espaços invisíveis no fim.
• Prefira opções curtas em <<choice>> e compare com elas.